::
:: System configuration batch file for Windows
::

@ECHO off

set PATH=%PATH%;"%ProgramFiles%\Common Files\Microsoft Shared\MSInfo"
set OS_VER=Win2k8

systeminfo | find "OS Name" >%TEMP%\osname.txt
FOR /F "usebackq delims=: tokens=2" %%i IN (%TEMP%\osname.txt) DO set OS_VERS_STRING=%%i
echo %OS_VERS_STRING% | find "Server 2003" 1>NUL
if %ERRORLEVEL% == 0 goto WIN2K3

echo %OS_VERS_STRING% | find "Server 2008" 1>NUL
if %ERRORLEVEL% == 0 goto WIN2K8
goto OS_CHECK_END

:WIN2K3
set OS_VER=Win2k3
goto OS_CHECK_END

:WIN2K8
set OS_VER=Win2k8

:OS_CHECK_END

::
:: MSINFO32 output
::
msinfo32.exe /nfo %1\msinfo32.nfo /categories +all

::
:: Check for crash dump files, if any.
::

FOR /F "tokens=3" %%i IN ('REG QUERY "HKLM\System\CurrentControlSet\Control\CrashControl" /v DumpFile') DO set dmpFile=%%i
FOR /F "tokens=3" %%i IN ('REG QUERY "HKLM\System\CurrentControlSet\Control\CrashControl" /v MinidumpDir') DO set miniDmpDir=%%i

echo ---------------------------Memory Dump------------------------------ > %1\CrashInfo.txt
echo. >> %1\CrashInfo.txt
cmd /C dir "%dmpFile%" >> %1\CrashInfo.txt 2>NUL

echo ---------------------------Mini Dumps------------------------------- >> %1\CrashInfo.txt
echo. >> %1\CrashInfo.txt
cmd /C dir "%miniDmpDir%" >> %1\CrashInfo.txt 2>NUL

::
:: Dump HKLM\Hardware\DeviceMap\SCSI contents
::

REG QUERY "HKLM\Hardware\DeviceMap\Scsi" /s > %1\DeviceMap.txt 2>NUL

::
:: Copy platform-specific configuration files
::

if (%OS_VER%)==(Win2k8) (
	copy %WINDIR%\System32\winevt\Logs\System.evtx %1\System.evtx 1>NUL
	copy %WINDIR%\System32\winevt\Logs\Application.evtx %1\Application.evtx 1>NUL
	copy %WINDIR%\inf\setupapi.app.log %1\setupapi.app.log 1>NUL
	cmd /C mpclaim.exe -v %1\mpio.txt 1>NUL
)
if (%OS_VER%)==(Win2k3) (
	copy %WINDIR%\System32\Config\SysEvent.evt %1\System.evt 1>NUL
	copy %WINDIR%\System32\Config\AppEvent.evt %1\Application.evt 1>NUL
)

:END
