VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Procedures"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit

Private p_colProcs  As Collection
Private p_modModule As CallTree.Module

Public Property Set Parent(modModule As CallTree.Module)
    ' Write-once property to specify parent.
    
    ' If property hasn't been set, set it.
    If p_modModule Is Nothing Then
        Set p_modModule = modModule
    End If
End Property

Public Property Get Parent() As CallTree.Module
    ' Return object that is this object's parent.
    Set Parent = p_modModule
End Property

Private Sub Class_Initialize()
    ' Create new private Collection object.
    Set p_colProcs = New Collection
End Sub

Function Add(strProcName) As CallTree.Procedure
    ' Add new Procedure object to Procedures collection.
    Dim prcProc As CallTree.Procedure

    Set prcProc = New Procedure
    
    ' Set Name property.
    prcProc.Name = strProcName
    
    Set prcProc.Parent = Me.Parent
    
    ' Add to private collection.
    p_colProcs.Add prcProc, strProcName
    
    ' Return reference to new Procedure object.
    Set Add = prcProc
End Function

Property Get Count() As Long
    Count = p_colProcs.Count
End Property

Property Get Item(varIndex As Variant) As CallTree.Procedure
Attribute Item.VB_UserMemId = 0
    On Error Resume Next
    Set Item = p_colProcs.Item(varIndex)
End Property

' NewEnum must return the IUnknown interface of a
' collection's enumerator.
Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
   Set NewEnum = p_colProcs.[_NewEnum]
End Function


