VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CallsTo"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit

Private p_colCalls  As Collection
Private p_prcProc   As CallTree.Procedure

Public Property Set Parent(calCallFrom As CallTree.Procedure)
    ' Write-once property to specify parent.
    
    ' If property hasn't been set, set it.
    If p_prcProc Is Nothing Then
        Set p_prcProc = calCallFrom
    End If
End Property

Public Property Get Parent() As CallTree.Procedure
    ' Return object that is this object's parent.
    Set Parent = p_prcProc
End Property

Private Sub Class_Initialize()
    ' Create new private Collection object.
    Set p_colCalls = New Collection
End Sub

Function Add(prcProc As CallTree.Procedure) As CallTree.CallTo
    ' Add new CallTo object to CallsTo collection.
    Dim calCallTo   As CallTree.CallTo
    Dim cvbProject  As CallTree.CustomVBProject
    Dim modModule   As CallTree.Module
    Dim prcEnumProc As CallTree.Procedure

    On Error GoTo Add_Err

    ' Create new CallTo object.
    Set calCallTo = New CallTree.CallTo
    
    ' Store reference to calling procedure.
    Set calCallTo.Procedure = prcProc
    
    ' Add to private collection.
    p_colCalls.Add calCallTo, prcProc.Name
    
    ' Return reference to new CallTo object.
    Set Add = calCallTo

Add_End:
    Exit Function

Add_Err:
    Select Case Err.Number
        Case 457
            ' Item already exists in collection. Error is
            ' silent.
            ' Denote procedures with the same name as ambiguous.
            Set cvbProject = prcProc.Parent.Parent
            For Each modModule In cvbProject.Modules
                For Each prcEnumProc In modModule.Procedures
                    If prcProc.Name = prcEnumProc.Name Then
                        prcEnumProc.Ambiguous = True
                    End If
                Next
            Next
        Case Else
            AddInErr Err
    End Select
    Set Add = Nothing
    Resume Add_End
End Function

Property Get Count() As Long
    Count = p_colCalls.Count
End Property

Property Get Item(varIndex As Variant) As CallTree.CallTo
Attribute Item.VB_UserMemId = 0
    Set Item = p_colCalls.Item(varIndex)
End Property

' NewEnum must return the IUnknown interface of a
' collection's enumerator.
Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
   Set NewEnum = p_colCalls.[_NewEnum]
End Function


