# S484ASAP.def: Collects Oracle Communications ASAP Information
# $Id: S484ASAP.def,v 1.5 2009/02/06 18:22:54 mschenke Exp $
# ARCS: $Header: /u02/webapps/workbench/cvs/RDA_4/src/scripting/lib/modules/S484ASAP.def,v 1.5 2009/02/06 18:22:54 mschenke Exp $
#
# Change History
# 20090206  KRA  Encode file names.

=head1 NAME

S484ASAP - Collect Oracle Communications ASAP Software Information

=head1 DESCRIPTION

This module collects Oracle Communications ASAP-related
information. The following reports can be generated and are regrouped under
C<ASAP>:

=cut

echo tput('bold'),'Processing ASAP module ...',tput('off')

# Initialization
var $ASAP_HOME = getSetting('ASAP_HOME')
var $TAIL      = getSetting('ASAP_TAIL')

var $TOC  = '%TOC%'
var $TOC2 = '%TOC2%'
var $TOP  = '[[#Top][Back to top]]'

toc '1:ASAP'

# Define the directory analysis macro
macro stat_tree
{var ($dir) = @arg
 import $TOP

 prefix
 {
 }
 call statDir('n',$dir)
 if hasOutput(true)
  write $TOP

 loop $fil (grepDir($dir,'^\.+$','nv'))
 {var $pth = catFile($dir,$fil)
  if testFile('dr',$pth)
  {next testFile('l',$pth)
   call stat_tree($pth)
  }
 }
}

# Source the profile
call backupEnv('asap')
call source(catCommand($ASAP_HOME,'Environment_Profile'),true)

=head2 product_info - Product Information

Collects a variety of Oracle Communications ASAP product information.

=cut

debug ' Inside ASAP module, getting product information'
report product_info
write '---+!! Application Information'
write $TOC

var $cmd = catCommand($ASAP_HOME,'scripts','status')
prefix
{write '---++ ASAP Applications Running'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

var $cmd = concat(catCommand($ASAP_HOME,'programs','sarm'),' -i')
prefix
{write '---++ sarm'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

var $cmd = concat(catCommand($ASAP_HOME,'programs','ctrl_svr'),' -i')
prefix
{write '---++ ctrl_svr'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

var $cmd = concat(catCommand($ASAP_HOME,'programs','fork_agent'),' -i')
prefix
{write '---++ fork_agent'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

var $cmd = concat(catCommand($ASAP_HOME,'programs','admn_svr'),' -i')
prefix
{write '---++ admn_svr'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

var $cmd = concat(catCommand($ASAP_HOME,'programs','asc_nep'),' -i')
prefix
{write '---++ asc_nep'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

var $cmd = concat(catCommand($ASAP_HOME,'programs','srp_emul'),' -i')
prefix
{write '---++ srp_emul'
 write '---### Using: ',encode($cmd)
}
call writeCommand($cmd)
if hasOutput(true)
 write $TOP

toc '2:[[',getFile(),'][rda_report][Application Information]]'

=head2 environment_profile - Environment Profile

Reports the environment profile.

=cut

debug ' Inside ASAP module, getting the environment profile'
report environment_profile
var $fil = catFile($ASAP_HOME,'Environment_Profile')
prefix
{write '---+ Oracle Communications ASAP Environment Profile'
 write '---## From: ',encode($fil)
}
call writeFile($fil)
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Environment Profile]]'

=head2 properties - Properties File

Reports Oracle Communications ASAP properties.

=cut

debug ' Inside ASAP module, getting property information'

report properties
var $fil = catFile($ASAP_HOME,'ASAP.properties')
prefix
{write '---+ Oracle Communications ASAP Properties File'
 write '---## From: ',encode($fil)
}
call writeFile($fil)
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Properties File]]'

=head2 configs - Configuration Files

Collects Oracle Communications ASAP configuration files.

=cut

debug ' Inside ASAP module, getting product information'
report configs
var $dir = catDir($ASAP_HOME,'config')
prefix
{write '---+!! Oracle Communications ASAP Configuration Files'
 write '---## Recursively Searched from ',encode($dir)
 write $TOC2
}
loop $fil (grepDir($dir,'^\.+$','nrv'))
{if testFile('fT',$fil)
 {write '---'
  write '---+',encode($fil)
  call writeFile($fil)
  write $TOP
 }
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Configuration Files]]'

=head2 core_file_analysis - Product Information

Analyzes core files.

=cut

debug ' Inside ASAP module, analyzing core files'
report core_file_analysis
prefix
{write '---+!! Core Files'
 write '---## Recursively Searched from ',encode($ASAP_HOME)
 write $TOC
}
loop $fil (grepDir($ASAP_HOME,'core','nr'))
{if testFile('fB',$fil)
 {write '---+',encode($fil)
  call writeCommand(concat('pstack ',$fil))
 }
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Core Files]]'

=head2 install_info - Installation Files

Collects Oracle Communications ASAP installation files.

=cut

debug ' Inside ASAP module, getting installation files'
report install_info
var $dir = catDir($ASAP_HOME,'install')
prefix
{write '---+ Oracle Communications ASAP Installation Information'
 write '---## Recursively Searched from ',encode($dir)
 write $TOC2
}
loop $fil (grepDir($dir,'^\.+$','nrv'))
{if testFile('T',$fil)
 {write '---'
  write '---+',encode($fil)
  call writeFile($fil)
  write $TOP
 }
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Installation Files]]'

=head2 java_information - Java Information

Collects Oracle Communications ASAP Java information.

=cut

debug ' Inside ASAP module, getting Java information'
report java_information
write '---+!! Java Information'
write $TOC

var $cmd = catCommand($ASAP_HOME,'JRE','bin','java')
write '---+ JRE Version'
write '---## Using: ',encode($cmd),' -version'
call writeCommand(concat($cmd,' -version 2>&1'))

var $dir = catDir($ASAP_HOME,'JLIB')
write '---+ JLIB Directory'
write '---## From: ',encode($dir)
loop $fil (grepDir($dir,'^\.+$','nrv'))
{next !testFile('f',$fil)
 write '---++',encode($fil)
 if match($fil,'\.jar$')
 {var $cmd = join(' ',\
                  catCommand($ASAP_HOME,'JRE','bin','jar'),'-tvf',$fil,'2>&1')
  write '---### Using: ',encode($cmd)
  call writeCommand($cmd)
 } 
 elsif testFile('T',$fil)
  call writeFile($fil)
 write $TOP
}
toc '2:[[',getFile(),'][rda_report][Java Information]]'

=head2 log_files - Log Files

Collects Oracle Communications ASAP log files.

=cut

debug ' Inside ASAP module, getting log files'
report log_files
prefix
{write '---+!! Oracle Communications ASAP Log Files'
 write '---## Recursively from ',encode($ASAP_HOME)
 write $TOC2
}
loop $fil (grepDir($ASAP_HOME,'log$','nr'))
{if testFile('T',$fil)
 {write '---+ ',encode($fil)
  write '---## (',getSize($fil),' bytes)'
  call writeTail($fil,$TAIL)
  write $TOP
 }
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Log Files]]'

=head2 diag_files - Diagnostic Files

Collects Oracle Communications ASAP diagnostic files.

=cut

debug ' Inside ASAP module, getting diagnostic files'
report diag_files
var $dir = catDir($ASAP_HOME,'DATA','logs')
write '---+!! Oracle Communications ASAP Diagnostic Files'
write '---## Recursively from ',encode($dir)
write $TOC2
loop $fil (grepDir($dir,'diag$','nr'))
{if testFile('T',$fil)
 {write '---+ ',encode($fil)
  write '---## (',getSize($fil),' bytes)'
  call writeTail($fil,$TAIL)
  write $TOP
 }
}
toc '2:[[',getFile(),'][rda_report][Diagnostic Files]]'

=head2 lib_files - Library Information

Collects Oracle Communications ASAP library information.

=cut

debug ' Inside ASAP module, getting library information'
report lib_files
var $dir = catDir($ASAP_HOME,'lib')
prefix
{write '---+ Oracle Communications ASAP Library Information'
 write '---## Recursively Searched from ',encode($dir)
}
call stat_tree($dir)
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Library Information]]'

=head2 object_files - Object Information

Lists Oracle Communications ASAP object files.

=cut

debug ' Inside ASAP module, listing object information'
report object_files
var $dir = catDir($ASAP_HOME,'objects')
prefix
{write '---+ Oracle Communications ASAP Object Information'
 write '---## Recursively Searched from ',encode($dir)
}
loop $fil (grepDir($dir,'^\.+$','nrv'))
 write $fil,'%BR%'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Object Information]]'

=head2 full_directory_listing - Full Directory Listing

Lists the content of the Oracle Communications ASAP directory structure.

=cut

debug ' Inside ASAP module, listing ASAP directory structure'
report full_directory_listing
write '---+ Oracle Communications ASAP Directory Structure Content'
write '---## Recursively Searched from ',encode($ASAP_HOME)
call stat_tree($ASAP_HOME)
toc '2:[[',getFile(),'][rda_report][Full Directory Listing]]'

# Restore the environment
call restoreEnv('asap')

=begin credits

=over 10

=item RDA 4.13: Robert Finley

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2009, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut