# S403ACFS.def: Collects ASM Cluster File System Information
# $Id: S403ACFS.def,v 1.3 2009/08/08 09:09:33 mschenke Exp $
# ARCS : $Header: /u02/webapps/workbench/cvs/RDA_4/src/scripting/lib/modules/S403ACFS.def,v 1.3 2009/08/08 09:09:33 mschenke Exp $
#
# Change History
# 20090808  DEM  Complete modinfo collection.

=head1 NAME

S403ACFS - Collects ASM Cluster File System Information

=head1 DESCRIPTION

This module collects ASM Cluster File System-related information.

The following reports can be generated and are regrouped under C<ASM Cluster
File System>:

=cut

echo tput('bold'),'Processing ACFS module ...',tput('off')

# Initialisation
var $ORACLE_HOME = getSetting('ASM_ORACLE_HOME','')
var $AGE         = getSetting('ACFS_AGE',15)
var $TAIL        = getSetting('ACFS_TAIL',1000)

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:ASM Cluster File System'

# Load the common macros
run library()

=head2 acfsutil - acfsutil Output

Collects F<acfsutil> command output.

=cut

if isUnix()
 var $cmd = catFile('/sbin','acfsutil')
else
 var $cmd
if testFile('fx',$cmd)
{var $cmd = concat(lastCommand(),' info fs')
 debug ' Inside ACFS module, gathering acfsutil information'
 report acfsutil
 prefix
 {write '---+!! acfsutil Command Output'
  write '---## Using: ',encode($cmd)
 }
 call writeCommand($cmd)
 if isCreated(true)
  toc '2:[[',getFile(),'][rda_report][acfsutil Output]]'
}
else
 return

=head2 crsctl - crsctl Output

Collects F<crsctl> command output.

=cut

if isUnix()
 var $cmd = catFile($ORACLE_HOME,'bin','crsctl')
else
 var $cmd = catFile($ORACLE_HOME,'bin','crsctl.exe')
else
 var $cmd = undef
if testFile('fx',$cmd)
{var $cmd = concat(lastCommand(),' stat res -p -init')
 debug ' Inside ACFS module, gathering crsctl information'
 report crsctl
 prefix
 {write '---+!! crsctl Command Output'
  write '---## Using: ',encode($cmd)
 }
 call writeCommand($cmd)
 if isCreated(true)
  toc '2:[[',getFile(),'][rda_report][crsctl Output]]'
}

=head2 modinfo - Module Information

On Linux, reports ACFS, ADVM, and OKS module information.

=cut

var $osn = getOsName()
if match($osn,'linux')
{debug ' Inside ACFS module, gathering modinfo information'
 report modinfo
 loop $lin (grepFile('/proc/modules','^(acfs|advm|oks)\s','i'))
 {var $mod = field('\s',0,$lin)
  prefix
  {if !isCreated()
   {write '---+!! Module Information'
    write $TOC
   }
   write '---+ Module ',uc($mod)
  }
  call writeCommand(concat('/sbin/modinfo ',$mod,' 2>&1'))
  if hasOutput(true)
   write $TOP
 }
 if isCreated(true)
  toc '2:[[',getFile(),'][rda_report][Module Information]]'
}

=head2 OKS Log Files

Collects Oracle Kernel Service (OKS) log files.

=cut

pretoc '2:OKS Log Files'
debug ' Inside ACFS module, gathering log files'
if isUnix()
 call sort_files(3,$TAIL,'/proc/oks/log')
elsif isWindows()
{if getEnv('SYSTEMROOT')
  var $sys = last
 else
  var ($sys) = command('echo %SystemRoot%')
 call sort_files(3,$TAIL,\
   grepDir(catDir($sys,'system32','drivers','acfs'),'okslog',\
           concat('im',$INST_AGE)))
}

=head1 SEE ALSO

L<library.def|modules::library>

=begin credits

=over 10

=item RDA 4.17: Jean-Marc Gaudron.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2009, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut