# S397BI.def: Collects Oracle Business Intelligence Enterprise Edition Info.
# $Id: S397BI.def,v 1.7 2009/04/30 12:55:13 mschenke Exp $
# ARCS: $Header: /u02/webapps/workbench/cvs/RDA_4/src/scripting/lib/modules/S397BI.def,v 1.7 2009/04/30 12:55:13 mschenke Exp $
#
# Change History
# 20090305  KRA  Support AS 11g install type.

=head1 NAME

S397BI - Collects Oracle Business Intelligence Enterprise Edition Information

=head1 DESCRIPTION

This module collects information related to Oracle Business Intelligence
Enterprise Edition, formerly known as Siebel Business Analytics.

The following reports can be generated and are regrouped under C<Oracle
Business Intelligence Enterprise Edition>:

=cut

echo tput('bold'),'Processing BI module ...',tput('off')

# Initialization
var $ORACLE_HOME = getSetting('ORACLE_HOME','')
var $BI_AGE      = getSetting('BI_LOG_AGE',5)
var $BI_TAIL     = getSetting('BI_TAIL',5000)

var $MNU = '1:Oracle Business Intelligence Enterprise Edition'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

# Collect the Oracle Business Intelligence information
if or(getSetting('ASIT_IN_USE'),\
      testDir('d',catDir($ORACLE_HOME,'bifoundation')))
{# Abort collection when merged
 if getSetting('ASIT_MERGE',true)
 {echo "BI collection performed by the ASIT module"
  return
 }

 # Load the common macros
 var ($CNT,%DUP) = (0)
 run BIr11()

 # Collect the generic information
 pretoc $MNU
 pretoc '1+:Oracle Home'
 call collect_bi_generic(catDir($ORACLE_HOME,'bifoundation'))
 unpretoc

 # Identify the repository opted
 var %rep
 call collect_bi_repo_list(\%rep)

 # Collect the data for each instance
 var $hom = catDir(getSetting('ASIT_INSTANCE_HOME',''))
 var %cmp
 loop $ins (get_instances($hom,'ASIT_INSTANCES'))
 {# Get the instance name and the relevant instance components
  var $dir = catDir($hom,$ins)
  var $dsc = get_components(\%cmp,$dir,$ins,\
    '^OracleBI(ClusterController|JavaHost|PresentationServices|Scheduler|\
               Server)Component$')

  # Skip instances without relevant components
  next !keys(%cmp)

  # Treat relevant components
  debug ' Inside BI module, analyzing instance ',$dsc
  if isTocCreated(true)
   pretoc '%SPLIT%'
  else
   pretoc $MNU
  pretoc "1+:'",$dsc,"' Instance"
  call collect_bi_instance($dsc,$dir,\%cmp,\%rep)
  unpretoc 2
 }
}
else
{var $BI_HOME = getSetting('BI_HOME','')
 var $BI_DATA = getSetting('BI_DATA','')
 pretoc $MNU

 # Load the common macros
 run library()

=head2 bi_version - Version Information

Gathers version information.

=cut

 debug ' Inside BI module, getting version information'
 report bi_version
 call cat_file(catDir($BI_HOME,'server','Document'),'version.txt')
 if isCreated(true)
  toc '2:[[',getFile(),'][rda_report][Version Information]]'

=head2 present_config - Presentation Server Configuration

Gathers presentation server configuration information.

=cut

 pretoc '2:Configuration Files'

 debug ' Inside BI module, getting presentation server configuration'
 report present_config
 call cat_file(catDir($BI_DATA,'web','config'),'instanceconfig.xml')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Presentation Server]]'

=head2 server_config - Server Configuration

Gathers server configuration information.

=cut

 debug ' Inside BI module, getting server configuration'
 report server_config
 call cat_file(catDir($BI_HOME,'server','Config'),'NQSConfig.INI')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Server]]'

=head2 cluster_config - Cluster Controller Configuration

Gathers cluster controller configuration information.

=cut

 debug ' Inside BI module, getting cluster controller configuration'
 report cluster_config
 call cat_file(catDir($BI_HOME,'server','Config'),'NQClusterConfig.INI')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Cluster Controller]]'
 unpretoc

=head2 Log Files

Gathers important log files.

=cut

 pretoc '2:Log Files'

 debug ' Inside BI module, getting server log'
 report server_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQServer.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Server]]'

 debug ' Inside BI module, getting query log'
 report query_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQQuery.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Query]]'

 debug ' Inside BI module, getting scheduler log'
 report scheduler_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQScheduler.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Scheduler]]'

 debug ' Inside BI module, getting administration tool log'
 report admin_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQSAdminTool.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Administration Tool]]'

 debug ' Inside BI module, getting install log'
 report install_log
 call tail_file(catDir($BI_HOME,'log'),'install.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Install]]'

 debug ' Inside BI module, getting cluster controller log'
 report cluster_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQCluster.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Cluster Controller]]'

 pretoc '3:Presentation Server'
 var $dir = catDir($BI_DATA,'web','log')
 loop $fil (grepDir($dir,'^sawlog.*\.log$',concat('ipm',$BI_AGE)))
 {report concat('web_',$fil)
  call tail_file($dir,$fil,$BI_TAIL)
  if isCreated(true)
   toc '4:[[',getFile(),'][rda_report][',encode($fil),']]'
 }
 unpretoc

 pretoc '3:Javahost'
 var $dir = catDir($BI_DATA,'web','log','javahost')
 loop $fil (grepDir($dir,'^jhost0\.log\.',concat('ipm',$BI_AGE)))
 {report concat('java_',$fil)
  call tail_file($dir,$fil,$BI_TAIL)
  if isCreated(true)
   toc '4:[[',getFile(),'][rda_report][',encode($fil),']]'
 }
 unpretoc 2

=head2 repository - Repositories

Gathers repositories.

=cut

 var $rep = getSetting('BI_REPOSITORY','All')
 if compare('eq',$rep,'All')
  var @fil = grepDir(catDir($BI_HOME,'server','Repository'),'\.rpd$','inp')
 elsif compare('eq',$rep,'None')
  var @fil = ()
 else
  var @fil = (catFile($BI_HOME,'server','Repository',$rep))
 run BIinfo(2,@fil)
 unpretoc
}

=head1 SEE ALSO

L<library.def|modules::library>, L<BIinfo.def|modules::BIinfo>,
L<BIr11.def|modules::BIr11>

=begin credits

=over 10

=item RDA 4.11: Ravindrasinh Parmar.

=item RDA 4.15: John Whitaker.

=item RDA 4.16: Greg Cook, Andrew Salt.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2009, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut