# S352ECM.def: Controls Oracle Enterprise Content Management 11g Data Collection
# $Id: S352ECM.def,v 1.1 2009/05/04 15:42:00 mschenke Exp $
# ARCS: $Header: /u02/webapps/workbench/cvs/RDA_4/src/scripting/lib/modules/S352ECM.def,v 1.1 2009/05/04 15:42:00 mschenke Exp $
#
# Change History
# 20090408  KRA  Initial version.

=head1 NAME

S352ECM - Controls Oracle Enterprise Content Management 11g Data Collection

=head1 DESCRIPTION

This module defines common settings for all Oracle Enterprise Content
Management 11g modules and gathers information that is common for Oracle
Enterprise Content Management components.

Oracle Enterprise Content Management includes:

=over 3

=item o Distributed Document Capture

=item o Document Capture

=item o Imaging and Process Management

=item o Information Rights Management

=item o Universal Content Management

=item o Universal Online Archive

=item o Universal Records Management

=back

The following reports can be generated and are regrouped under C<Enterprise
Content Management>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing ECM module ...',tput('off')

# Initialization
var $ORACLE_HOME = catDir(getSetting('ORACLE_HOME',''))
var $ECM_JDK     = catDir(getSetting('ECM_JDK',catDir($ORACLE_HOME,'jdk')))
var $TAIL        = getSetting('RDA_TAIL',1000)

var $ASSISTANTS_HOME  = catDir($ORACLE_HOME,'assistants')
var $CFGTOOLLOGS_HOME = catDir($ORACLE_HOME,'cfgtoollogs')
var $INSTALL_HOME     = catDir($ORACLE_HOME,'install')

var $IPM_HOME = catDir($ORACLE_HOME,'ipm')
var $IRM_HOME = catDir($ORACLE_HOME,'irm')
var $UCM_HOME = catDir($ORACLE_HOME,'ucm')
var $UOA_HOME = catDir($ORACLE_HOME,'uoa')
var $URM_HOME = catDir($ORACLE_HOME,'urm')

var $OH  = quote($ORACLE_HOME)
var $OH1 = concat('^',$OH,'[\\\/]')
var $OH2 = concat('^',$OH,'\b')

var $MNU = 'Enterprise Content Management'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

# Load the common macros
run library()

=head1 ORACLE HOME COLLECTIONS

=head2 error - Installation Type Error

Indicates that the specified Oracle home does not contain information related
to an Enterprise Content Management type.

=cut

# Indicate installation type error
macro dsp_error
{echo ' Error: The specified Oracle home does not contain appropriate \
               information'
 report error
 write '** Error: The specified Oracle home is not an Enterprise Content \
        Management installation of Oracle Application Server 11g.**%BR%'
 write '%BR%'
 if @arg
 {write '|*Oracle Home*|',encode($arg[0]),' |'
  write '|*Install Name*|',$arg[1],' |'
  write '|*Install Version*|',$arg[2],' |'
 }
 toc '2:[[',getFile(),'][rda_report][Installation Type Error]]'
}

# Validate the installation type
debug ' Inside ECM module, validating the installation type'
var $flg = false
var $fil = catFile($ORACLE_HOME,'inventory','ContentsXML','comps.xml')
if testFile('fr',$fil)
{if xmlFind(xmlLoadFile($fil),'PRD_LIST/TL_LIST/COMP')
 {var ($xml) = (last)
  var $ver = xmlValue($xml,'VER')
  var $dsc = xmlData(xmlFind($xml,'EXT_NAME'))
  if !match($dsc,'^Application Server 11g ECM',true)
   var $flg = true
 }
}
pretoc '1:',$MNU
if $flg
 call dsp_error($ORACLE_HOME,$dsc,$ver)
elsif !or(testDir('d',$IPM_HOME),\
          testDir('d',$IRM_HOME),\
          testDir('d',$UCM_HOME),\
          testDir('d',$UOA_HOME),\
          testDir('d',$URM_HOME))
 call dsp_error()

=head2 Install and Configuration

Gathers the Oracle Application Server configuration and installation files.

=cut

debug ' Inside ECM module, gathering install and configuration information'
pretoc '2:Installation and Configuration'
call sort_files(3,$TAIL,\
  grepDir($ASSISTANTS_HOME,'\.log$','dir'),\
  grepDir($CFGTOOLLOGS_HOME,'\.(ini|log|properties|xml)','dir'),\
  grepDir($INSTALL_HOME,'\.(ini|log)','dir'))
unpretoc

if testDir('d',catDir($ORACLE_HOME,'diagnostics'))
{debug ' Inside ECM module, gathering diagnostics information'
 pretoc '2:Diagnostics'
 call sort_files(3,$TAIL,\
   grepDir(lastDir(),'\.((conf|ini|xml|properties|err)$|log)|\~','dir'))
 unpretoc
}

=head2 jdk_info - JDK Information

Checks for the available JDK and reports its version.

=cut

debug ' Inside ECM module, gathering jar files'
report jdk_info
prefix
{write '---+!! JDK Information'
 write $TOC
}
var @tbl = grepDir($ECM_JDK,'^java(\.exe)?$','inr')
loop $cmd (@tbl)
{if testFile('fx',$cmd)
 {write '---++ JDK Location: ',encode(replace($cmd,$OH2,'$OH'))
  call statFile('p',$cmd)
  var $cmd = quote($cmd,'x')
  write '---++++!! JDK Version'
  call writeCommand(concat($cmd,' -version 2>&1'))
  write '---++++!! JDK Full Version'
  call writeCommand(concat($cmd,' -fullversion 2>&1'))
  write $TOP
 }
}
if !hasOutput(true)
{write '---+ JDK information'
 write '**No JDK found.**'
}
toc '2:[[',getFile(),'][rda_report][JDK Information]]'

=head2 jdk_libs - Java Libs

Gathers information about all C<*.jar> files located in the common directory.
For each Jar file, the report collects file information and the output from
C<cksum>.

=cut

debug ' Inside ECM module, gathering Java libs information'
report java_libs
prefix
{write '---+!! Information about Java Libs'
 write '%TOC3-2%'
}
var $cmd = findCommand('cksum')
loop $jar (grepDir(catDir($ORACLE_HOME,'j2ee','home'),'\.jar$','inr'),\
           grepDir(catDir($ORACLE_HOME,'jlib'),'\.jar$','inr'),\
           grepDir(catDir($ORACLE_HOME,'lib'),'\.jar$','inr'),\
           grepDir(catDir($ORACLE_HOME,'jdbc','lib'),'\.(jar|zip)$','dir'))
{if testFile('f',$jar)
 {if match($jar,$OH2)
   write '---++ ',encode(replace($jar,$OH2,'$OH'))
  else
   write '---++ ',encode($jar)
  call statFile('p',$jar)
  if $cmd
  {write '---++++!! cksum: (checksum size filename)'
   call writeCommand(concat($cmd,' ',quote($jar,'x')))
  }
  write $TOP
 }
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Java Libs]]'

# Disable the group title in next index
if isTocCreated()
 toc '-:',$MNU

=head1 SEE ALSO

L<S301WLS.def|modules::S301WLS>,
L<S353UOA.def|modules::S353UOA>,
L<library.def|modules::library>

=begin credits

=over 10

=item RDA 4.16: Greg Cook, Andrew Salt.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2009, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut