# HCVEload.def: Collects HCVE Reports
# $Id: HCVEload.def,v 1.7 2009/01/14 11:41:42 ldens Exp $
# ARCS: $Header: /u02/webapps/workbench/cvs/RDA_4/src/scripting/lib/modules/HCVEload.def,v 1.7 2009/01/14 11:41:42 ldens Exp $
#
# Change History
# 20090114  LDE  Change the copyright notice.

=head1 NAME

HCVEload - Collects HCVE Reports

=head1 DESCRIPTION

This module gets reports generated by the Health Check/Validation Engine.

The following report is produced:

=head2 hcve - Health Check/Validation Engine

Gets reports generated by the Health Check/Validation engine.

=cut

macro get_hcve_link
 return concat(basename($arg[0],'.txt'),'.htm')

debug ' Inside LOAD module, gathering HCVE reports'
report hcve
prefix
{write '---+ Health Check/Validation Results'
 write '|*Rule Set*|*Results*|*Errors*|'
}
var $dir = getSetting('RPT_DIRECTORY')
var $pat = '<!-- Module:TSThcve Version:\S+ Report:(.*?) OS:'
var (%err,%res,%set) = ()
loop $fil (grepDir($dir,\
                   concat('^',getSetting('RPT_GROUP'),'_HCVE_.*\.txt$'),'i'))
{var ($set,$typ) = match($fil,'_HCVE_(.*)_(res|err)\.txt$',true)

 # Treat other file name formats
 if !$typ
 {var ($rpt) = grepFile(catFile($dir,$fil),$pat,'f')
  var ($rpt) = match($rpt,$pat)
  if match($rpt,'^(res|err)$')
   var ($set,$typ) = ('?',last)
  else
   var ($typ,$set) = match($rpt,'^HCVE_(res|err)_(.*)$')
 }

 # Store the report links
 if match($typ,'res',true)
  var $res{$set} = concat('[[',get_hcve_link($fil),'][_blank][results]]')
 elsif match($typ,'err',true)
  var $err{$set} = concat('[[',get_hcve_link($fil),'][_blank][errors]]')
}
loop $set (keys(%res))
 write '|',nvl(getHcveName($set),$set),'|',$res{$set},' |',$err{$set},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Health Check/Validation Engine]]'

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2009, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut