# DEVlib.def: Defines Common Macros for Oracle Developer
# $Id: DEVlib.def,v 1.3 2009/02/11 07:08:11 mschenke Exp $
# ARCS: $Header: /u02/webapps/workbench/cvs/RDA_4/src/scripting/lib/modules/DEVlib.def,v 1.3 2009/02/11 07:08:11 mschenke Exp $
#
# Change History
# 20090210  KRA  Make the index more consistant with previous releases.

=head1 NAME

DEVlib - Defines Common Macros for Oracle Developer

=head1 DESCRIPTION

This persistent sub module regroups macros that are common to Oracle Developer.

The following macros are available:

=cut

# Make the module persistent and share macros
keep $KEEP_BLOCK,@SHARE_MACROS
var @SHARE_MACROS = ('get_file','get_install','get_forms_java_directory')

=head2 S<get_file($fil,$lgt,$pre,$lvl)>

This macro looks for a simple file and inserts a link in the RDA menu
structure.

=cut

macro get_file
{var ($fil,$lgt,$pre,$lvl) = @arg

 if testFile('fr',$fil)
 {import $OI2,$OH2,$TOP
  keep $cnt
  if !$pre
  {incr $cnt
   var $pre = sprintf('f%02d_',$cnt)
  }
  var $nam = basename($fil)
  report concat($pre,$nam)
  if $lgt
  {prefix
   {write '---+ Last ',$lgt,' Lines of File ',encode($nam)
    write '---## Information Taken from ',encode($fil)
   }
   call writeTail($fil,$lgt)
  }
  else
  {prefix
   {write '---+ Display File ',encode($nam)
    write '---## Information Taken from ',encode($fil)
   }
   call writeFile($fil)
  }
  if hasOutput(true)
  {write $TOP
   if $lvl
    var $lnk = replace($fil,$OI2,'$OI')
   else
    var $lnk = replace($fil,$OH2,'$OH')
   toc concat(nvl($lvl,4),':[['),getFile(),'][rda_report][',$lnk,']]'
  }
 }
}

=head2 S<get_install($dir,$str,$typ)>

This macro looks for installation log for the specified Oracle Developer
component type.

=cut

macro get_install
{var ($dir,$str,$typ) = @arg
 var $dir = catDir($dir,concat($str,$typ))
 var $pre = concat('inventory_',$typ,'_')
 if testDir('r',$dir)
 {var ($fil) = grepDir($dir,'^context.xml$','ir')
  call get_file($fil,0,$pre)
  loop $fil (grepDir(dirname($fil),'^install.*log.xml$','ip'))
   call get_file($fil,0,$pre)
 }
}

=head2 S<get_forms_java_directory($frm)>

This macro lists C<forms90/java> or C<forms/java> directory contents.

=cut

macro get_forms_java_directory
{var ($frm) = @arg
 import $OH2,$TOC,$TOP

 # List forms90/java or forms/java directory contents
 if testDir('d',$frm)
 {var $dir = catDir($frm,'java')
  report forms_java
  prefix
  {write '---+!! Forms Java Directories'
   write $TOC
  }
  loop $itm ($dir,grepDir($dir,'^[^\.]','dpr'))
  {if testDir('d',$itm)
   {write '---++ ',encode($itm)
    call statDir('n',$itm)
    write $TOP
   }
  }
  if isCreated(true)
   toc '3:[[',getFile(),'][rda_report][',replace($dir,$OH2,'$OH'),']]'
 }
}

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2009, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut