# DDCload.def: Collects Oracle Database Diagnostic Collector Reports
# $Id: DDCload.def,v 1.3 2008/02/08 14:43:14 mschenke Exp $
# ARCS: $Header: /home/cvs/repository/RDA_4/src/scripting/lib/modules/DDCload.def,v 1.3 2008/02/08 14:43:14 mschenke Exp $
#
# Change History
# 20080208  MSC  Improve formatting.

=head1 NAME

DDCload - Collects Oracle Database Diagnostic Collector Reports

=head1 DESCRIPTION

=head2 oraddc - Database Diagnostic Collector

This module gets reports generated by Oracle Database Diagnostic Collector
(ORADDC) during the last 15 days.

=cut

# Initialisation
var @tb_mon = (\
  '','Jan','Feb','Mar','Apr','May','Jun','Jul','Aug','Sep','Oct','Nov','Dec')
var %tb_dmp = ('A','Hang Analyze Dump',\
               'C','Locking Contention Report',\
               'H','Shared Pool (Heap) Dump',\
               'L','Library Cache Dump',\
               'R','Row Cache Dump',\
               'S','System State Dump',\
               'W','Session Wait Events Report')
var %tb_met = ('-','None',\
               'B','Blocking Sessions',\
               'E','Wait Event Sessions',\
               'O','Oracle Process Identifiers',\
               'P','Process Identifiers',\
               'S','Session Identifiers',\
               'U','Session User')
var %tb_prc = ('E','Process Error Stack',\
               'O','Operating System Trace',\
               'P','Process State Dump',\
               'S','Process Stack',\
               'T','10046 Trace')

# Collect recent files
debug ' Inside LOAD module, gathering ORADDC reports'
report oraddc
prefix
{write '---+ Oracle Database Diagnostic Collector (ORADDC) Results'
 write 'Limited to ORADDC runs done in last 15 days%BR% '
 write '|*Date*|*Run%BR%Options*|*Background%BR%Process*|*Process%BR%Method*|\
         *Process%BR%Arguments*|*Process%BR%Reports*|*Reports*|*Sleep%BR%Time*|'
}
var $dir = getSetting('RPT_DIRECTORY')
loop $fil (grepDir(catDir($dir,'extern'),\
                   concat('^',getSetting('RPT_GROUP'),'_DDC_\d{10}_log\.txt$'),\
                   'iptm15'))
{# Decode the ORADDC options
 next !grepFile($fil,'ORADDC Options','f')
 var ($opt,@dmp,@prc) = (field('\|',2,last))
 var @opt = split(':',$opt)
 var ($met,$arg) = split('\/',$opt[2])
 var $arg = replace($arg,',',', ',true)
 if !length($met)
  var $met = '-'
 loop $itm (split(',',$opt[3]))
 {if $itm
   var @prc = (@prc,nvl($tb_prc{$itm},$itm))
 }
 loop $itm (split(',',$opt[4]))
 {if $itm
   var @dmp = (@dmp,nvl($tb_dmp{$itm},$itm))
 }

 # Decode the date
 var ($yea,$mon,$day,$hou,$min) = \
  match($fil,'_DDC_(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)_log\.txt$',true)
 incr $yea,2000

 # Add the log in the report
 write '|[[',catDir('extern',basename($fil,'.txt')),'.htm][_blank][',\
       $day,'-',$tb_mon[$mon],'-',$yea,' ',$hou,':',$min,']]|',\
       $opt,' |',replace($opt[1],',','%BR%',true),' |',\
       nvl($tb_met{$met},$met),' |',$arg,' |',\
       join('%BR%',@prc),' |',join('%BR%',@dmp),' |',$opt[5],' |'
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Database Diagnostic Collector]]'

=head1 COPYRIGHT NOTICE

Copyright (c) 2002-2008, Oracle. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle, JD Edwards, PeopleSoft, and Siebel are registered trademarks of Oracle
Corporation and/or its affiliates. Other names may be trademarks of their
respective owners.

=cut